// Jednostavna animacija u Scilabu.
// 
clear

// vidi dokumentaciju
set("figure_style", "old")

nt=101;   // broj vremenskih intervala
nx=101;   // broj prostornih točaka
T=linspace(0,6*%pi,nt);
x=linspace(0,2*%pi,nx);

// 
pravokutnik=[-0.05, -1.05, 2*%pi+0.05, 1.05];
xselect()   // stavi grafički prozor u prvi plan
xbasc()     // obriši prozor (driver Rec)

dr=driver()    // Uzmi defaultni grafički driver    
driver("X11")  // Postavi driver X11      

[ci,cx,cy,cw]=xclick();   // čekaj na klik da kreneš


xset("pixmap",1)  // crtaj u buffer
xset('wwpc')      // očisti buffer
y=cos(T(1)-2*x);
plot2d(x,y,style=1,frameflag=1,...
       axesflag=1, leg='y(x,t)=cos(t-2*x)',...
       rect=pravokutnik)
xtitle("Jednostavna animacija")
xset("wshow")  //  prikaži buffer
realtimeinit(0.05);realtime(0)
//pause
for i=2:nt
    xclea(-0.02, 1.02, 2*%pi+0.04, 2.04) // očisti dio buffera 
                                         // (osim koord osi)
    y=cos(T(i)-2*x);
    realtime(i);                         // sinhronizacija
                                         // crtaj u buffer
    plot2d(x,y,style=1,frameflag=0, axesflag=0)
    xset("wshow")                        // prikaži buffer
end
xset("pixmap",0);   // dalje crtaj direktno na ekran
driver(dr);         // defaultni driver